My mIRC
The major thing I've noticed about people's IRC clients are background color. That's wallpaper. And the default color of choice for mIRC is white.
One unique thing about my mIRC is that I use 2 themes, daytime, and, nighttime. From the hours of 6 a.m. to 6 p.m., my mIRC is in its daytime theme (white background), and from the hours of 6 p.m. and 6 a.m., my mIRC is under nighttime theme (black background). Of course, I can /daytime or /nighttime at anytime to override. And when I open my mIRC, it checks the time of day to whether to /daytime or /nighttime.
The images, being screenshots, are screen-sized, so there is no point to shrink it to show it on this page. This function was made to help my eyes at night. In San Diego, if I got out of my bed in the middle of the night, and turned on the monitor, the white background color hurted my eyes so I had to dim the screen. This nighttime theme helped me beneficially.
Source aliases.
/daytime {
/timernight -o 18:00 1 1 /nighttime
/color background 0
/color normal 1
/color own 1
/color listbox 0
/color listbox text 1
/color action 1
/color list 0
/color kick 1
/color whois 1
}
/nighttime {
/timerday -o 6:00 1 1 /daytime
/color background 1
/color normal 0
/color own 0
/color listbox 1
/color listbox text 0
/color action 0
/color list 1
/color kick 0
/color whois 0
}
Remote.
on *:start: {
if ($time(HH) > 06) && ($time(HH) < 18) { /daytime }
if ($time(HH) > 18) || ($time(HH) < 06) { /nighttime }
}
* Note that, this on start event is not my complete on start event, other stuff happens.
Another unique property of my mIRC is that on the titlebar it shows a clock with the second, how many users I am with on the current network, how many bans are in the active window if it is a channel, the total number of single lines in my buffer (which may take up more than 1 line), and the total number of blinking private message windows I have. For on my start event:
/.timertime -o 0 1 /scid $!activecid $chr(124) /titlebar $!asctime(hh:nn:ss tt) $!countnicks users $!iif($line($active,0) != 0,$line($active,0) lines,$null) $!iif($ibl($active,0) != 0,$ibl($active,0) bans,$null) $!iif($globalcoloredqueries != 0,$globalcoloredqueries pms,$null)
/countnicks {
.hmake allnicks 100
.scid $activecid
var %c = $chan(0)
while (%c) {
var %n = $nick($chan(%c), 0)
while (%n) {
.hadd allnicks $nick($chan(%c), %n) 1
.dec %n
}
.dec %c
}
var %number = $hget(allnicks, 0).item
.hfree allnicks
if ($isid) return %number
/echo -s %number total nicks.
}
Original credits go to Oliver Runge of Germany for coding the custom $countnicks identifier.
localcoloredqueries {
var %q = $query(0),%x = 0
while (%q) {
if ($window($query(%q)).sbcolor == message) inc %x
if ($window($query(%q)).sbcolor == highlight) inc %x
dec %q
}
if ($isid) return %x
/echo -s %x
}
globalcoloredqueries {
var %t
scid -a $(inc %t $localcoloredqueries, 0)
if ($isid) return %t
/echo -s %t
}
Lastly, but not importantly, I am reminded of my age when I open my mIRC. In my on start event:
/echo -s You are $betterduration($calc($ctime - $ctime(March 19 1988 16:16:00))) old ( $+ $calc(($ctime - $ctime(March 19 1988 16:16:00)) / 31557600) years).It looks like: You are x years, y days, a hours, b minutes, and c seconds +/- ~< 60 seconds old (x.****** years).
betterduration {
var %lifeseconds = $abs($1)
var %age, %years, %days, %hours, %minutes, %seconds, %temp
%years = $int($calc(%lifeseconds / 31557600))
if (%years != 0) %age = %years year $+ $iif(%years > 1,s) $+ ,
%temp = $calc(%lifeseconds - (%years * 31557600))
%days = $int($calc(%temp / 86400))
if (%days != 0) %age = %age %days day $+ $iif(%days > 1,s) $+ ,
%temp = $calc(%temp - (%days * 86400))
%hours = $int($calc(%temp / 3600))
if (%hours != 0) %age = %age %hours hour $+ $iif(%hours > 1,s) $+ ,
%temp = $calc(%temp - (%hours * 3600))
%minutes = $int($calc(%temp / 60))
if (%minutes != 0) %age = %age %minutes minute $+ $iif(%minutes > 1,s) $+ ,
%seconds = $calc(%temp % 60)
if (%seconds != 0) %age = %age and %seconds second $+ $iif(%seconds > 1,s) +/- ~< 60 seconds
if ($right(%age, 1) == $chr(44)) return $left(%age, -1)
return %age
}
And just for some gee-whiz curiosity, I do run a grammar script, further scripts in private message, and miscellaneous other stuff to eliminate idiots.
I believe in the self-dense scripts rather than offensive attacks for war events. This means that when I get banned while op, I do not ban, but only unban myself (with the exception of *!*@* as $banmask). When I get kicked while opped, I rejoin the channel, rather than kick the kicker. And when I get deopped, I reop myself, rather than deop the deopper. Of course, after so and so time, I stop, to be the first to end it all..of course. All of this, is to prevent mass controversial drama when I am not at the keyboard, of course.
Sometimes an op may kick a regular user by mistake of the tab key. Or on the assumption that the user rejoins on kick or on invite. Well, if I was kicked as a regular user or voice of the channel, I /notice the op a way for him and less likely her to make my mIRC rejoin the channel by a /notice again. This allows any user to have me join almost any channel on IRC, which is fine.
And most importantly?when my name is called. Because my nick is Neal on almost every network, I often use Neal instead of $me. But I use both in case my nick isn?t Neal.. When my nick or name is called, my mIRC /splay Ding.wav, the text with the time, channel, and nick echos to my status window of that network, the channel or query button is changed to a flashing green color so I know where to look, and the entire string is in red text. I use both highlights and remotes, taking what I like from both.
Remote source.
on *:text:*:#: {
if ($wildtok($1-,*Neal*,0,32)) && (!$istok(%ignore,$nick,44)) && ($chan != $active) {
/echo -s You have been called by $nick in $iif($chan,$chan,$nick) from saying, " $+ $1- $+ " at $asctime(h:nn:ss) $+ . | /splay Ding.wav
}
}
Note that this is *not* my on text event.
Query windows.
Whenever a user joins or parts a channel, or kicks or gets kicked from a channel, or messages or actions in a common channel that I am in, or disconnects from the network, and I accordingly have a private message window open for them, their such event if echo?d to my private message window with them, just for the sake of information. This is especially the case of importance when random idiots private message me and I care to know what channels they join or leave, or what they say. Of course, this could also be used as a way to spy on people (for those that think ahead), requiring common channels.
Example event: for on kick.
on *:kick:#: {
if ($query($knick)) {
/echo $knick $timestamp * $knick was kicked by $nick in $chan ( $+ $1- $+ )
}
if ($query($nick)) {
/echo $nick $timestamp * $nick kicks $knick in $chan ( $+ $1- $+ )
}
}
Some mIRC philosophies and some scripts and aliases I got.
Articles for newbies.
How to download mIRC (for people that have never used mIRC before).
Some must do and for beginning mIRC users.