My Aliases
My basic aliases, these are still under construction.
/a {
if ($1 == $null) {
/scon -a if ($status == connected) /away
}
if ($1 != $null) {
/scon -a if ($status == connected) && ($network != Efnet) && ($network != Dalnet) /.away Global away message for $totalserver $+ / $+ $scon(0) networks: $1- /msg $!me !commands
/scon -a if ($status == connected) && ($network == Efnet) && ($network != Dalnet) /.away Global away $totalserver $+ / $+ $scon(0) networks: $1- /msg $!me !commands
/scon -a if ($status == connected) && ($network != Efnet) && ($network == Dalnet) /.away Global away message for $totalserver $+ / $+ $scon(0) networks: $1- Speak in English. /msg $!me !commands
/set %away $1-
}
}
/b {
if ($1 != $null) {
if ($active != Status Window) && (!$query($active)) {
if ($1 ison $active) {
if ($2 == $null) {
/ban -u765 $active $$1 2
}
if ($2 != $null) {
/ban -u765 $active $$1 $2
}
}
if ($1 !ison $active) {
/mode $active +bbbbbbbbbbbb $1-
inc %b | /.timerunban $+ %b 1 765 /mode $chan -b $1
}
}
if ($active == Status Window) {
/mode $$1 +b
}
if ($query($active)) {
if ($1 == $active) {
var %b = 1
while ($comchan($$1,%b).op) {
/mode $ifmatch +b $$1
/ban $ifmatch $1 4
inc %b
}
}
}
}
if ($1 == $null) {
if ($active != Status Window) && (!$query($active)) {
/mode $active +b
}
if ($active == Status Window) {
var %b = 1, %calculate
while ($ibl($chan(%b),0)) {
%calculate = $calc(%calculate + $ifmatch)
inc %b
}
/echo -s There are a total of %calculate bans in all your channels on this network. | ;dec %b
}
if ($query($active)) {
var %b = 1
while ($comchan($$1,%b).op) {
/ban $ifmatch $active 4
inc %b
}
}
}
}
/c /clear
My /d alias is for channel mode d, /disconnect, "delete" private messages, and /disable.
/d {
if ($1 == $null) {
if ($chan) {
if (d !isincs $chan($active).mode) {
/mode $active +d
}
if (d isincs $chan($active).mode) {
/mode $active -d
}
}
if ($active == Status Window) {
/disconnect | /disconnect
}
if ($query($active)) {
if ($exists($window($active).logfile)) && (!$exists(C:\mIRC\Junk\ $+ $mkfn($window($active)) $+ . $+ $network $+ . $+ log)) {
/rename $window($active).logfile C:\mIRC\Junk\ $+ $mkfn($window($active)) $+ . $+ $network $+ . $+ log | /remove $window($active).logfile | /close -m $active | /halt
}
if ($exists($window($active).logfile)) && ($exists(C:\mIRC\Junk\ $+ $mkfn($window($active)) $+ . $+ $network $+ . $+ log)) {
/copy -a $window($active).logfile C:\mIRC\Junk\ $+ $mkfn($window($active)) $+ . $+ $network $+ . $+ log | /remove $window($active).logfile | /close -m $active | /halt
}
}
}
if ($1 != $null) {
/disable $1
}
}
/e {
if ($1 != $null) {
if ($left($1,1) == #) {
/enable $$1
}
}
if ($1 != $null) {
if ($left($1,1) != #) {
/mode $active +e $$1
}
}
}
/f {
var %temp = $+(sendkeys,$ticks)
.comopen %temp WScript.Shell
.comclose %temp $com(%temp, SendKeys, 3, *bstr, % $+ f)
}
/g /groups $1-
/h {
if ($1 == $null) {
/hop $active
}
if ($1 != $null) {
if ($1 !ishop $active) {
/mode $active +hhhhhhhhhhhh $1-
}
if ($1 ishop $active) {
/mode $active -hhhhhhhhhhhh $1-
}
}
}
My /i alias is for channel mode i, /invite, "info," and "ignore." "Info" is for /ChanServ or /NickServ info. As I have an IRC philosophy against /ignore, "ignore" just closes the private message window..
/i {
if ($chan) {
if ($me isop $active) {
if ($1 == $null) {
if (i !isincs $chan($active).mode) {
/mode $active +i
}
if (i isincs $chan($active).mode) {
/mode $active -i
}
}
if ($1 != $null) && ($chr(42) isin $1) {
/mode $active +I $1
}
if ($1 != $null) && ($chr(42) !isin $1) {
/invite $$1 $active
}
}
if ($me !isop $active) {
/chanserv invite $active $me
}
}
if ($query($active)) {
/close -m $active
}
if ($active == Status Window) {
if ($left($1,1) == $chr(35)) {
/chanserv info $1
}
if ($left($1,1) != $chr(35)) {
/nickserv info $1
}
}
}
/j {
if ($1 == $null) {
/join $active
}
if ($1 != $null) && ($chr(58) !isin $1) {
/join #$$1
}
if ($1 != $null) && ($chr(58) isin $1) && ($chr(35) !isin $1) {
/mode $active +j $1
}
}
/k {
if ($chan) && ($1 != $null) {
if ($2- == $null) {
/kick $active $1 $1
}
if ($2- != $null) {
/kick $active $1 $2-
}
}
if ($query($active)) {
var %k = 1
while ($comchan($active,%k).op) {
if ($1 == $null) {
/kick $ifmatch $active $active
}
if ($1 != $null) {
/kick $ifmatch $active $1-
}
inc %k
}
}
}
/l {
if ($active == Status Window) && ($1 == $null) {
/list
}
if ($chan) {
if ($me isop $active) && ($1 == $null) {
if (L !isincs $chan($active).mode) {
/mode $active +L
}
if (L isincs $chan($active).mode) {
/mode $active -L
}
}
if ($me isop $active) && ($1 != $null) {
/mode $active +l $1
}
}
}
/m {
if ($chan) {
if ($1 == $null) {
if (m !isincs $chan($active).mode) {
/mode $active +m
}
if (m isincs $chan($active).mode) {
/mode $active -m
}
}
if ($1 != $null) {
/mode $active $$1 $2-
}
}
if (!$chan) {
/mode $1-
}
}
My /n alias is for /nick, /notice, and /names.
/n {
if ($2 == $null) {
/nick $$1
}
if ($2 != $null) {
/notice $$1 $2-
}
if ($left($1,1) == $chr(35)) {
/names $$1
}
}
/o {
if ($chan) {
if (($1 == $null) && ($me !isop $active)) {
/chanserv : $+ op # $me
}
if (($1 == $null) && ($me isop $active)) {
/chanserv : $+ deop # $me
}
if (($1 != $null) && ($me isop $active)) {
if ($1 !isop $active) {
/.raw mode $active + $+ $str(o,$numtok($1-,32)) $1-
}
if ($1 isop $active) {
/.raw mode $active - $+ $str(o,$numtok($1-,32)) $1-
}
}
if (($1 != $null) && ($me !isop $active)) {
if ($1 !isop $active) {
/chanserv : $+ op # $1-
}
if ($1 isop $active) {
/chanserv : $+ deop # $1-
}
}
}
if ($active == Status Window) {
var %temp = $+(sendkeys,$ticks)
.comopen %temp WScript.Shell
.comclose %temp $com(%temp, SendKeys, 3, *bstr, % $+ o)
}
}
/p {
var %temp = $+(sendkeys,$ticks)
.comopen %temp WScript.Shell
.comclose %temp $com(%temp, SendKeys, 3, *bstr, % $+ p)
}
/q {
if (!$query($active)) {
if ($2 == $null) {
/query $$1
}
if ($2 != $null) {
/queryrn $$1 $$2
}
}
if ($query($active)) {
/queryrn $query($active) $$1
}
}
/r /remote $1
/s {
if ($1 == $null) {
if ($status == disconnected) {
/server
}
}
if ($1 != $null) {
if ($chr(46) isin $1) {
/server -m $$1
}
}
}
/t {
if ($chan) {
if ($1 == $null) {
/raw -q topic $active :
}
if ($1 != $null) {
/topic $active $chan($active).topic $1-
}
}
if ($active == Status Window) {
/titlebar $1-
}
}
/u {
/mode $active +u $1
}
/v {
if ($chan) {
if (($1 == $null) && ($me !isvoice $active)) {
/chanserv : $+ voice # $me
}
if (($1 == $null) && ($me isvoice $active)) {
/chanserv : $+ devoice # $me
}
if (($1- != $null) && ($me isop $active)) {
if ($1 !isvoice $active) {
/.raw mode # + $+ $str(v,$numtok($1-,32)) $1-
}
if ($1 isvoice $active) {
/.raw mode # - $+ $str(v,$numtok($1-,32)) $1-
}
}
if (($1- != $null) && ($me !isop $active)) {
if ($1 !isvoice $active) {
/chanserv : $+ voice # $1-
}
if ($1 isvoice $active) {
/chanserv : $+ devoice # $1-
}
}
}
}
/w {
if ($left($1,1) != $chr(35)) {
/whois $$1 $$1
}
if ($left($1,1) == $chr(35)) {
/who $$1
}
}